DSXchange

Code: Select all

SUBROUTINE ManyOutputFiles(SourceFile, ErrorCode)
DEFFUN OpenTextFile(FileName, OpenMode, WriteMode, Logging) CALLING "DSU.OpenTextFile"
$INCLUDE UNIVERSE.INCLUDE FILEINFO.H
$UNDEFINE TESTING

ErrorCode = 0
ReadCount = 0
LineCount = 0
SeparatorCount = 0

* Open source file for reading.
hSource = OpenTextFile((SourceFile), "R", "A", "Y")
If Not(FileInfo(hSource, FINFO$IS.FILEVAR)) 
Then
   ErrorCode = 1
   GoTo MainExit
End

* Initialize file name counter component.  Open first file for writing.
Counter = 1
FileName = "MyFile_" : Fmt(Counter,"R%4")
hTarget = OpenTextFile(FileName, "W", "O", "Y")
If Not(FileInfo(hTarget,FINFO$IS.FILEVAR)) 
Then 
   ErrorCode = 1
   GoTo MainExit
End

* Main loop reads lines from source file
Loop
While ReadSeq Line From hSource

   ReadCount += 1

   If Line = "(***end of report***)"
   Then

      * Close current file, generate new name and open new file for writing.
      SeparatorCount += 1
      CloseSeq hTarget
      Counter += 1
      FileName = "MyFile_" : Fmt(Counter,"R%4")
      hTarget = OpenTextFile(FileName, "W", "O", "Y")
      If Not(FileInfo(hTarget,FINFO$IS.FILEVAR)) 
      Then 
         ErrorCode = 1
         GoTo MainExit
      End

   End
   Else

      * Not a separator; just write line to current output file.
      WriteSeq Line To hTarget
      Then
         LineCount += 1
      End

   End

Repeat

MainExit:
CloseSeq hSource
CloseSeq hTarget

$IFDEF TESTING
   Message = "Rows read by routine = " : RowCount
   Message<-1> = "Separators found = " : SeparatorCount
   Message<-1> = "Lines written by routine = " : LineCount
   Message<-1> = "Number of output files = " : Counter
   Call DSLogInfo(Message, "Testing ManyOutputFiles routine")
$ENDIF

RETURN

Code: Select all

awk '
BEGIN \
{
    # Set the file number.
  file_number = 1;
  output_to = "file" filenumber ".txt"
}
  
($0 == "(***end of report***)") \
{
    # Increment the file name.
  file_number++;
  output_to = "file" filenumber ".txt"
    # Don't output the end of report line to the file.
  next;
}
{
    # Output the line to named file
  print > output_to;
}' your_input_file_here