DSXchange

Code: Select all

********************************************************************************
*
* Name:      GetParameterFromFile
* 
* Arguments: ConfigFileName   - The path and filename of the config file
*            ParamName        - The parameter within the file to retrieve
*
* Expects file with the contents in the form: ParamName=ParamValue
*
* Open file passed in 'ConfigFileName'. Read until finding the line
* where ParamName equals the 'ParamName' argument value passed in.
* Return the ParamValue found.
*
* If the 'ParamName' value passed in was not found in the file
* return @Null
********************************************************************************
Equate TransformName To "GetParameterFromFile"


   * Trim input args and assign to local vars
   ConfigFile = Trim(ConfigFileName, ' ', 'B')
   ParameterName = Trim(ParamName, ' ', 'B')
      

   ParamFound = @False

   * Try to open the file...
   OpenSeq ConfigFile To ConfigFileVar
   On Error
      Msg = 'Error opening parameters file, ' : SQuote(ConfigFile): ', status = ' : Status()
      Call DSLogFatal(Msg, TransformName )
      Abort
   End
   Else
      Msg = 'Cannot open parameters file, ' : SQuote(ConfigFile): ', status = ' : Status() : ' for Parameter ' : SQuote(ParameterName)
      Call DSLogFatal(Msg, TransformName )
      Abort
   End

   * We have successfully opened the file
   * Now read the parameter list from the file.
   If FileInfo(ConfigFileVar, 0)
   Then
      Loop
      While ReadSeq Line From ConfigFileVar
         ParName = Trim(Field(Line,"=",1,1))
         ParamValue = Trim(Field(Line,"=",2,1))

         If UpCase(ParName) = UpCase(ParameterName) Then
            ParamFound = @True
            Exit
         End
         
      Repeat
      CloseSeq ConfigFileVar
   End

   If ParamFound Then
      Ans = ParamValue
   End Else
      Ans = @Null
      Msg = 'Cannot find parameter ' : SQuote(ParamName): ', status = ' : Status()
      Call DSLogFatal(Msg, TransformName )


   End